@Text (式言語)

任意の値を文字列に変換します。

構文

@Text( value ; format-string )

パラメータ

value

数値、日時、文字列、文字列のリスト、またはリッチテキスト。文字列に変換する値を指定します。

注: リッチテキストの変換は Release 6 で新しく追加されました。

format-string

文字列または文字列リスト。オプション。最高 4 つの書式文字列を指定できます (下表参照)。書式文字列によって、返される文字列の表示形式を指定します。value のデータ型がすでに文字列である場合は、format-string は無視されます。

戻り値

textValue

文字列または文字列リスト。指定した value が文字列に変換されて返されます。format-strings を指定した場合は、それらの書式文字列が適用されます。

日時構成要素を指定した @Text

日時の書式文字列の構成要素は 4 種類あります。書式には構成要素を 4 つまで指定できますが、1 つの種類からは 1 つしか指定できません。

記号	意味
D0	月、日、年
D1	月、日、現在の年でなければ年
D2	月、日
D3	月、年
T0	時、分、秒
T1	時、分
Z0	時刻をこのタイムゾーンの時刻に変換
Z1	このタイムゾーンでない場合に限りタイムゾーンを表示
Z2	常にタイムゾーンを表示
S0	日付のみ
S1	時刻のみ
S2	日付と時刻
S3	日付、時刻、Today または Yesterday
Sx	指定する値が時刻、日付、時刻と日付の両方のいずれかであることがわかっているが、正確な書式を予測できない場合に使用する

数値の値を指定した @Text

数値の場合は、次の構成要素を自由に組み合わせて書式文字列を作成します。

記号	意味
G	標準形式 (有効数字のみ)
F	固定形式 (標準小数部桁数)
S	指数形式 (E 表記)
C	通貨形式 (小数点以下 2 桁)
,	千の単位で区切り (米国の書式を使用)
%	パーセント書式
()	負の数値をカッコで囲む
number	精度の桁数

使用法

パラメータがリストである場合、この関数はリストの各要素ごとに処理され、戻り値は同じ数の要素を持つリストになります。

数値を文字列に変換すると、その数値は算術計算には使用できなくなります。

リッチテキストを文字列に変換すると、添付ファイルと書式 (タブとスペースを除く) はすべて失われます。文書の中でリッチテキストを変換する場合は、文書を保存しなければ変換結果は表示されません。

リッチテキストの変換は、列式では機能しません。リッチテキストフィールドの内容をプレーンテキストに変換するには、@Abstract を使用します。その後、プレーンテキストフィールドをビューで参照します。例えば、plainText という名前の非表示の計算結果フィールドに次のコードを追加してから、ビューの列のデフォルト値として "plainText" を設定すると、RTField の内容を表示できます。

@Abstract([TextOnly];15360;"";"RTField")

列内の数値または日付の変換に @Text を使用する場合は、警告を使用します。サーバーによって管理されているデータベースでは、数値と日付は常にその管理サーバーのオペレーティングシステムの形式設定を使用して表示されます。また、データベースにアクセスするクライアントかデータベースを管理するサーバーのどちらかで日付または数値の形式設定が変更された場合も、ビューを全面的に作成し直さなければならなくなることがあります。

例

次の例では、123.45 が返されます。
```
@Text(123.45)
```
次の例では、[Sales] フィールドが 800 のときに、$800.00 が返されます。
```
@Text(Sales;"C,2")
```
次の例では、8.00E+02 が返されます。
```
@Text(800;"S")
```
次の例では、8.00E+02 と -6.00E+02 がリストで返されます。
```
@Text(800 : (-600);"S")
```
次の例では、04/11/93 10:43 AM が返されます。
```
@Text(@Now)
```
次の例では、04/11 が返されます。
```
@Text(@Now;"D1S0")
```
次の例では、10:43:30 AM が返されます。
```
@Text(@Now;"D1S1")
```
次の例では、04/93 10:43 AM が返されます。
```
@Text(@Now;"D3T1")
```
次の例では、リッチテキストの [本文] フィールドの内容から添付ファイルと書式を除いた文字列が返されます。
```
@Text(Body)
```

[ShipDate] フィールドに格納されている数値の日付を文字の日付に変換するには、次のコードを使用します。[ShipDate] の内容が [08/31/2002] ならば、結果は「August 31, 2002」となります。

@If( @IsTime(ShipDate); 
@Text(@Select(@Month(ShipDate); "January"; "February"; "March"; "April"; "May"; "June"; "July"; "August"; "September"; "October"; "November";  "December"))  + " " +
@Text(@Day(ShipDate)) + ", " + @Text(@Year(ShipDate));
 "No date given")

クロスリファレンス

LotusScript® 言語の CStr 関数

LotusScript NotesRichTextItem クラスの GetFormattedText メソッド

Java™ RichTextItem クラスの getFormattedText メソッド