GetEntries (NotesCalendar - LotusScript)

指定した時刻範囲内でカレンダーエントリを取得します。

定義位置

構文

Set entriesVariant = notesCalendar.GetEntries( startNotesDateTime , endNotesDateTime , [ skipcount& ] , [ maxreturn& ] )

パラメータ	説明
`start`	NotesDateTime. エントリの開始時刻。
`end`	NotesDateTime. エントリの終了時刻。終了時刻が開始時刻より後の時刻になっていない場合は、例外が発生します。
`skipcount`	Long。取得操作を開始する前にスキップするエントリの数。デフォルトは 0 です。
`maxreturn`	Long。返されるエントリの最大数。`skipcount` も `maxreturn` も指定しない場合は、範囲内のすべてのエントリが返されます。

戻り値	説明
`Variant 型`	範囲内のカレンダーエントリ。エントリが存在しない場合は空配列。各配列要素は NotesCalendarEntry 型です。

使用法

最後の 2 つのパラメータは、 EntriesProcessed とともに使用し、後続の操作でエントリを処理します。最後の 2 つのパラメータの使用例については、EntriesProcessed を参照してください。

例

このエージェントにより、現在のユーザーについて、今日と明日のカレンダー情報とスケジュール情報が取得されます。

Sub Initialize
	Dim session As New NotesSession
	Dim maildb As New NotesDatabase("", "")
	Dim cal As NotesCalendar
	Dim dt1 As NotesDateTime
	Dim dt2 As NotesDateTime
	Dim db As NotesDatabase
	Dim doc As NotesDocument
	Dim body As NotesRichTextItem
	REM Get calendar for current user
	Call maildb.Openmail()
	Set cal = session.getCalendar(maildb) ' Not In ref pane
	Set dt1 = session.createdatetime("Today 08")
	Set dt2 = session.Createdatetime("Tomorrow 17")
	Set db = session.CurrentDatabase
	REM Create document to post results
	Set doc = db.CreateDocument
	doc.Form = "main"
	doc.Subject = "Today and tomorrow"
	Set body = doc.Createrichtextitem("body")
	REM Get entries and put in body of document
	ForAll cale In cal.Getentries(dt1, dt2)
		Call body.Appendtext(cale.Read())
		Call body.Addnewline(1)
	End ForAll
	Call body.Appendtext(cal.ReadRange(dt1, dt2))
	Call doc.Save( True, True )
End Sub

クロスリファレンス

Java™ NotesCalendar クラスの getEntries メソッド