EntriesProcessed (NotesCalendar - LotusScript®)

読み込み専用。 GetEntries 操作と ReadRange 操作によって処理されたエントリの数。

定義位置

NotesCalendar

データ型

Long 型

構文

取得する場合: entries& = notesCalendar.EntriesProcessed

使用法

このプロパティは GetEntries と ReadRange の第 3 パラメータとして使用し、後続の操作でエントリを処理します。

例

このエージェントは、GetEntries を使用して、現在のユーザーについて今日と明日のカレンダー情報とスケジュール情報を取得します。

Sub Initialize
	Dim session As New NotesSession
	Dim maildb As New NotesDatabase("", "")
	Dim cal As NotesCalendar
	Dim cale As NotesCalendarEntry
	Dim entries As Variant
	Dim dt1 As NotesDateTime
	Dim dt2 As NotesDateTime
	Dim db As NotesDatabase
	Dim doc As NotesDocument
	Dim body As NotesRichTextItem
	REM Get calendar for current user
	Call maildb.Openmail()
	Set cal = session.getCalendar(maildb)
	Set dt1 = session.createdatetime("Today 08")
	Set dt2 = session.Createdatetime("Tomorrow 17")
	Set db = session.CurrentDatabase
	REM Create document to post results
	Set doc = db.CreateDocument
	doc.Form = "main"
	doc.Subject = "Today and tomorrow"
	Set body = doc.Createrichtextitem("body")
	REM Get entries and put in body of document
	entries = cal.Getentries(dt1, dt2, 0, 1)
	While Not IsEmpty(entries)
		Set cale = entries(0)
		Call body.Appendtext(cale.Read())
		Call body.Addnewline(1)
		entries = cal.Getentries(dt1, dt2, cal.Entriesprocessed, 1)
	Wend
	Call doc.Save( True, True )
End Sub

このエージェントは、ReadRange を使用して、現在のユーザーについて今日と明日のカレンダー情報とスケジュール情報を取得します。

Sub Initialize
	Dim session As New NotesSession
	Dim maildb As New NotesDatabase("", "")
	Dim cal As NotesCalendar
	Dim entrystring As String
	Dim dt1 As NotesDateTime
	Dim dt2 As NotesDateTime
	Dim db As NotesDatabase
	Dim doc As NotesDocument
	Dim body As NotesRichTextItem
	REM Get calendar for current user
	Call maildb.Openmail()
	Set cal = session.getCalendar(maildb)
	Set dt1 = session.createdatetime("Today 08")
	Set dt2 = session.Createdatetime("Tomorrow 17")
	Set db = session.CurrentDatabase
	REM Create document to post results
	Set doc = db.CreateDocument
	doc.Form = "main"
	doc.Subject = "Today and tomorrow"
	Set body = doc.Createrichtextitem("body")
	REM Get entries and put in body of document
	entrystring = cal.ReadRange(dt1, dt2, 0, 1)
	While entrystring <> ""
		Call body.Appendtext(entrystring)
		Call body.Addnewline(1)
		entrystring = cal.ReadRange(dt1, dt2, cal.Entriesprocessed, 1)
	Wend
	Call doc.Save( True, True )
End Sub

クロスリファレンス

Java™ NotesCalendar クラスの EntriesProcessed プロパティ