例: NotesDatabase class

次のスクリプトは NotesDatabase オブジェクト db を作成し、New を使用して 1 つのデータベースを割り当てます。データベースはサーバー Barcelona の Domino データディレクトリの最上部にあります。データベースがある場合、New は自動的にデータベースを開くため、データベースのプロパティとメソッドにすぐにアクセスできます。
```
Dim db As NotesDatabase
Set db = New NotesDatabase( "Barcelona", "plan.nsf" )
Messagebox( db.Title )
```
次のスクリプトの実行結果は前の例と同じです。ただし、NotesDatabase オブジェクト db の宣言と New の呼び出しが 1 つの行に記述されています。
```
Dim db As New NotesDatabase( "Barcelona", "plan.nsf" )
Messagebox( db.Title )
```
次のスクリプトは、IsOpen を使用して、データベース QUACK.NSF が現在のコンピュータに存在するかどうかを調べます。存在しない場合、スクリプトは Create メソッドを使用してデータベースをディスクに新規作成します。
```
Dim db As New NotesDatabase( "", "quack.nsf" )
If db.IsOpen Then
  Messagebox( "The database quack.nsf already exists." )
Else
  Messagebox( "Creating the database quack.nsf...")
  Call db.Create( "", "", True )
  db.Title = "Ducks of North America"
End If
```
次のスクリプトは、db オブジェクトの宣言内で New を呼び出します。呼び出された New により、db オブジェクトが Senses ディレクトリ内のデータベースに割り当てられます (Senses ディレクトリは、Domino データディレクトリ内に格納されています)。
このスクリプトをクライアントで実行すると、ローカルコンピュータの CLUNK.NSF データベースが起動します。

このスクリプトをサーバー Khartoum で実行すると、Khartoum の CLUNK.NSF データベースが起動します。
```
Dim db As New NotesDatabase _
( "", "senses¥sounds¥clunk.nsf" )
```
Macintosh で CLUNK.NSF が Senses フォルダ内の Sounds フォルダに存在する場合、スクリプトは次のようになります。
```
Dim db As New NotesDatabase _
( "", "senses:sounds:clunk.nsf" )
```
次のスクリプトは Brian Flokka に現在のデータベースの [編集者]のアクセス権を与えます。現在のデータベースとはスクリプトが実行されているデータベースです。NotesSession の CurrentDatabase プロパティを使用すると、スクリプトでファイル名を指定する必要がありません。このため、スクリプトを簡単にデータベース間で移行できます。
```
Dim session As New NotesSession
Dim db As NotesDatabase
Set db = session.CurrentDatabase
Call db.GrantAccess( "Brian Flokka", ACLLEVEL_EDITOR )
```
次のスクリプトは Open メソッドを使用してデータベースがサーバー Asuncion にあるかどうかを調べます。データベースがあるとき、スクリプトは ACL に [Supervisors] グループを追加します。データベースがないときは、スクリプトは何も実行しません。
```
Dim db As New NotesDatabase( "", "" )
If db.Open( "Asuncion", "salesdocs.nsf" ) Then
  Call db.GrantAccess( "Supervisors", ACLLEVEL_EDITOR )
End If
```
次のスクリプトは、New を OpenIfModified メソッドを使用して、データベースがある日付以降に変更されている場合にのみデータベースを開く方法を示します。スクリプトは現在のサーバー上の SALESDOCS.NSF が昨日から変更されたかどうかを調べ、変更されている場合はデータベースを開いて圧縮します。
```
Dim db As New NotesDatabase( "", "" )
Dim dateTime As New NotesDateTime( "Today" )
Call dateTime.AdjustDay( -1 )
If db.OpenIfModified( "", "salesdocs.nsf", dateTime ) Then
  Call db.Compact
End If
```

次のスクリプトは New と CreateFromTemplate メソッドを使用して、新規のディスカッションデータベースをサーバー Juno に作成します。

Dim template As New NotesDatabase _
( "Anchorage", "discuss.ntf" )
Dim brandNewDb As NotesDatabase
Set brandNewDb = template.CreateFromTemplate _
( "Juno", "suggest.nsf", True )
brandNewDb.Title = "Suggestions for Giving Campaign 1996"