例: GetItemValue method

Dim session As NotesSession
Dim db As NotesDatabase
Dim dc As NotesDocumentCollection
Dim doc As NotesDocument
Set session = New NotesSession
Set db = session.CurrentDatabase
Set dc = db.UnprocessedDocuments 'This property only works in an agent that runs against a set of documents.

Set doc = dc.GetFirstDocument

1. 次のスクリプトは、文書の Subject アイテムの内容をダイアログボックスに表示します。この場合、GetItemValue は要素が 1 つの配列を返すため、コードは subj( 0 ) を使用して第 1 番目の要素にアクセスします。

   Dim subj As Variant
   subj = doc.GetItemValue( "Subject" )
   Messagebox( subj( 0 ) )

2. 次のスクリプトは拡張クラス構文を使用して、上記の例と同じ内容を実行します。

   Dim subj As Variant
   subj = doc.Subject
   Messagebox( subj( 0 ) )

3. 次のスクリプトは doc の quarterlyRevenue アイテムの値それぞれを集計して、結果を totalRevenue アイテムに配置します。quarterlyRevenue アイテムは数値リストです。totalRevenue アイテムは数値です。例えば、quarterlyRevenue が 50; 60; 70; 80 を含むとき、totalRevenue には値 260 が割り当てられます。

   Dim total As Integer
   Dim money As Variant
   total = 0
   money = doc.GetItemValue( "quarterlyRevenue" )
   Forall m In money
     total = total + m
   End Forall
   Call doc.ReplaceItemValue( "totalRevenue", total )
   Call doc.Save( False, True )

4. 次のスクリプトは拡張クラス構文を使用して、上記の例と同じ内容を実行します。

   Dim total As Integer
   Dim money As Variant
   total = 0
   money = doc.quarterlyRevenue
   Forall m In money
     total = total + m
   End Forall
   doc.totalRevenue = total
   Call doc.Save( False, True )

5. 次のスクリプトは、リッチテキストアイテム Body の内容を取得します。アイテムの内容は 1 つの文字列で返されます。そして、スクリプトは取得内容を新規のメールメモの [本文] フィールドに配置します。

   Sub Initialize
     Dim memo As NotesDocument
     Set memo = New NotesDocument( db )
     Dim bodytext As Variant
     bodytext = doc.GetItemValue( "Body" )
     Call memo.ReplaceItemValue( "Body", bodytext )
     Call memo.ReplaceItemValue( "Subject", _
     "Here's some plain text" )
     Call memo.ReplaceItemValue( "Form", "Memo" )
     Call memo.Send( False, _
     "dbattersly @ purple.peoplepleaser.org @ internet" )
   End Sub

6. 次のスクリプトは拡張クラス構文を使用して、上記の例と同じ内容を実行します。

   Sub Initialize
     Dim memo As NotesDocument
     Set memo = New NotesDocument( db )
     memo.Body = doc.Body
     memo.Subject = "Here's some plain text" 
     memo.Form = "Memo" 
     Call memo.Send( False, _
     "dbattersly @ purple.peoplepleaser.org @ internet" )
   End Sub