Read (NotesCalendarEntry - LotusScript®)

カレンダーエントリを iCalendar 形式でレンダリングします。

定義位置

構文

Set entry$ = notesCalendarEntry.Read( [ recurid$ ] )

パラメータ	説明
`recurid`	String 型。反復するカレンダーイベントの反復識別子 (`RECURRENCE-ID` アイテム)。反復識別子の形式は、UTC 形式での時刻です (`20120913T160000Z` など)。

戻り値	説明
`String`	`iCalendar` 形式のカレンダーエントリ。

可能性のある例外 (lsxbeerr.lss)	値	テキスト	説明
`lsERR_NOTES_ERR_INVALIDID`	4757	無効 ID	NotesCalendarEntry オブジェクトの識別子が無効です。
`lsERR_NOTES_ERR_RECURID_NOTFOUND`	4808	反復識別子が見つかりません。	NotesCalendarEntry オブジェクトの反復識別子が無効です。
`lsERR_NOTES_ERR_IDNOTFOUND`	4814	ID が見つかりません	NotesCalendarEntry オブジェクトの反復識別子がカレンダーのエントリを示していないか、反復識別子の `scope` と `recurid` がありません。

使用法

このメソッドは、エントリの完全な iCalendar データを返します。繰り返し発生するエントリの場合は、データに複数の VEVENT エントリが含まれる場合があります。

例

このエージェントは、指定された UID のカレンダーエントリ (繰り返し発生するエントリの場合は最初のインスタンス) を読み込みます。

Sub Initialize
	Dim session As New NotesSession
	Dim maildb As New NotesDatabase("", "")
	Dim cal As NotesCalendar
	Dim cale As NotesCalendarEntry
	Dim uid As String
	Dim calestr As String
	Dim recurid As String
	Dim i As Integer
	Dim db As NotesDatabase
	Dim doc As NotesDocument
	Dim body As NotesRichTextItem
	uid = session.Getenvironmentstring("currentuid")
	If uid = "" Then
		MessageBox "No current UID",, "Error"
		Exit sub
	End If
	recurid = session.Getenvironmentstring("currentrecurid")
	Call maildb.Openmail()
	Set cal = session.getCalendar(maildb)
	Set cale = cal.Getentry(uid)
	If recurid = "" Then
		calestr = cale.Read()
	Else
		calestr = cale.Read(recurid)
	End If
	REM Write results to document
	Set db = session.Currentdatabase
	Set doc = db.Createdocument()
	doc.Form = "main"
	doc.Subject = "Calendar entry"
	Set body = doc.Createrichtextitem("body")
	body.Appendtext(calestr)
	Call doc.Save(true, true)
End Sub

クロスリファレンス

Java™ NotesCalendarEntry クラスの read メソッド