例: ReadText method

次のエージェントは、テキストファイルを読み込み、その内容を現在のデータベース内の新規文書の Body アイテムに保存します。ユーザーはファイルの名前を指定しますが、拡張子 .txt は指定しません。次のエージェントは、Subject アイテムの内容に対してファイル名を使用します。

Sub Initialize
  Dim session As NotesSession
  Dim db As NotesDatabase
  Dim dc As NotesDocumentCollection
  Dim doc As NotesDocument
  Dim stream As NotesStream
  Dim pathname As String
  pathname = "c:¥StreamFiles¥"
  Set session = New NotesSession
  Set db = session.CurrentDatabase
  Set dc = db.UnprocessedDocuments
  Set doc = dc.GetFirstDocument
  Set stream = session.CreateStream
  REM Use name of text file as subject
  subject$ = Inputbox$("Name of file")
  pathname = pathname & subject$ & ".txt"
  If Not stream.Open(pathname, "ASCII") Then
    Messagebox pathname,, "Open failed"
    Exit Sub
  End If
  If stream.Bytes = 0 Then
    Messagebox pathname,, "File has no content"
    Exit Sub
  End If
  Set doc = New NotesDocument(db)
  Call doc.ReplaceItemValue("Form", "Main Topic")
  Call doc.ReplaceItemValue("Subject", subject$)
  Call doc.ReplaceItemValue("Body", stream.ReadText())
  Call stream.Close
  Call doc.save(True, True)
End Sub

次のエージェントは、最初の例に似ていますが、一度に 1 行ずつファイルを読み込みます。エージェントは、ストリームの最後まで新規文書の Body アイテムにテキストを追加します。

Sub Initialize
  Dim session As NotesSession
  Dim db As NotesDatabase
  Dim dc As NotesDocumentCollection
  Dim doc As NotesDocument
  Dim stream As NotesStream
  Dim pathname As String
  pathname = "c:¥StreamFiles¥"
  Set session = New NotesSession
  Set db = session.CurrentDatabase
  Set dc = db.UnprocessedDocuments
  Set doc = dc.GetFirstDocument
  Set stream = session.CreateStream
  REM Use name of text file as subject
  subject$ = Inputbox$("Name of file")
  pathname = pathname & subject$ & ".txt"
  If Not stream.Open(pathname, "ASCII") Then
    Messagebox pathname,, "Open failed"
    Exit Sub
  End If
  If stream.Bytes = 0 Then
    Messagebox pathname,, "File has no content"
    Exit Sub
  End If
  Set doc = New NotesDocument(db)
  Call doc.ReplaceItemValue("Form", "Main Topic")
  Call doc.ReplaceItemValue("Subject", subject$)
  Dim body As New NotesRichTextItem(doc, "Body")
  counter% = 0
  Do
    counter% = counter% + 1
    Call body.AppendText("[LINE " & counter% & "] ")
    buffer$ = stream.ReadText(STMREAD_LINE, EOL_CRLF)
    REM Discard lines with only LF + CR
    While buffer$ = Chr(13) & Chr(10) _
    And (Not stream.IsEOS)
      buffer$ = stream.ReadText(STMREAD_LINE)
    Wend
    Call body.AppendText(buffer$)
  Loop Until stream.IsEOS
  Call stream.Close
  Call doc.save(True, True)
End Sub