例: Formula property (NotesReplicationEntry - LotusScript®)

Sub Initialize
  REM Get local database
  dbName$ = _
  Inputbox$("Database name", _
  "Enter name of local database")
  Dim db As New NotesDatabase("", dbName$)
  Dim rep As NotesReplication
  Dim re As NotesReplicationEntry
  If Not db.IsOpen Then
    Messagebox "No local database",, dbName$
    Exit Sub
  End If
  
  REM Get source and destination computers
  source$ = Inputbox$("Source", _
  "Enter name of source computer")
  If Instr(1, source$, "Any Server", 5) > 0 Then
    source$ = "-"
  End If
  destination$ = _
  Inputbox$("Destination", _
  "Enter name of destination computer")
  If Instr(1, destination$, "Any Server", 5) > 0 Then
    destination$ = "-"
  End If
  
  REM Get replication entry
  Set rep = db.ReplicationInfo
  Set re = rep.GetEntry(source$, destination$, False)
  If re Is Nothing Then
    Messagebox _
    "No replication entry for " & source$ & _
    " and " & destination$,, _
    "No such replication entry"
    Exit Sub
  End If
  
  REM Set formula
  re.Formula = _
  Inputbox$("Enter valid replication formula", _
  "Formula", "@All")
  Call re.Save
  Messagebox re.Formula,, _
  "Formula for " & source$ & " and " & destination$
End Sub