例: FontStyle property

次のエージェントは、太字と斜体が設定されているかどうかを示します。

Sub Initialize
  Dim session As New NotesSession
  Dim db As NotesDatabase
  Dim view As NotesView
  Dim vc As NotesViewColumn
  Set db = session.CurrentDatabase
  Set view = db.GetView("Categorized")
  Set vc = view.Columns(0)
  If (vc.FontStyle And VC_FONT_BOLD) = VC_FONT_BOLD Then
    msg1$ = "Bold is set"
  Else
    msg1$ = "Bold is not set"
  End If
  If (vc.FontStyle And VC_FONT_ITALIC) = _
  VC_FONT_ITALIC Then
    msg2$ = "Italic is set"
  Else
    msg2$ = "Italic is not set"
  End If
  Messagebox msg1$ & Chr(13) & msg2$,, "Font styles"
End Sub

次のエージェントは、文字スタイルを太字から斜体 (斜体から太字) に切り替えます。

Sub Initialize
  Dim session As New NotesSession
  Dim db As NotesDatabase
  Dim view As NotesView
  Dim vc As NotesViewColumn
  Set db = session.CurrentDatabase
  Set view = db.GetView("Categorized")
  Set vc = view.Columns(0)
  If vc.FontStyle = VC_FONT_BOLD Then
    vc.FontStyle = VC_FONT_ITALIC
  Else
    vc.FontStyle = VC_FONT_BOLD
  End If
  Messagebox vc.FontStyle,, "New font style"
End Sub

他の属性に影響を与えずに 1 つのスタイルを設定するには、次の形式の論理構成を使用します。
```
vc.FontStyle = _
vc.FontStyle Or VC_FONT_BOLD
```
他の属性に影響を与えずに 2 つのスタイルを設定するには、次の形式の論理構成を使用します。
```
vc.FontStyle = _
vc.FontStyle Or VC_FONT_BOLD Or VC_FONT_ITALIC
```
他の属性に影響を与えずに 1 つのスタイルの設定を解除するには、次の形式の論理構成を使用します。
```
vc.FontStyle = _
vc.FontStyle And (Not VC_FONT_BOLD)
```
他の属性に影響を与えずに 2 つのスタイルの設定を解除するには、次の形式の論理構成を使用します。
```
vc.FontStyle = _
vc.FontStyle And (Not (VC_FONT_BOLD Or VC_FONT_ITALIC))
```