例: DialogBox method

次のスクリプトはボタンがクリックされると [Policy] フォームを使用してダイアログボックスに文書を開きます。[Policy] フォームの最初のレイアウト領域はダイアログボックスに合う大きさに変更されます。
```
Sub Click(Source As Button)
  Dim workspace As New NotesUIWorkspace
  Call workspace.DialogBox _
  ( "policy", True, True, True, True, _
  False, False, "Policy" )
End Sub
```

次のスクリプトは [DirectReports] というフォームを使用して現在の文書を表示します。現在の文書と [DirectReports] フォームはどちらも [HeadCount] という数値フィールドを表示します。[HeadCount] がダイアログボックスで編集されることがあります。編集されると、現在の文書の [HeadCount] のフィールド値が変更されます。スクリプトは DialogBox を呼び出す前後で [HeadCount] フィールドを比較して、変更があるときは [TotalHeadCount] フィールドを更新します。例えば、[HeadCount] が 5 増えると、スクリプトは [TotalHeadCount] を 5 増やします。

Sub Click(Source As Button)
  Dim workspace As New NotesUIWorkspace
  Dim uidoc As NotesUIDocument
  Dim oldHeadCount, newHeadCount, _
  totalHeadCount As Integer
  Set uidoc = workspace.CurrentDocument
  oldHeadCount = Cint( uidoc.FieldGetText( "HeadCount" ) )
  totalHeadCount = Cint _
  ( uidoc.FieldGetText( "TotalHeadCount" ) )    
  Call workspace.DialogBox( "DirectReports", True, True )
  ' HeadCount may have changed, so get new value
  newHeadCount = Cint( uidoc.FieldGetText( "HeadCount" ) )    
  If ( oldHeadCount <> newHeadCount ) Then
    ' HeadCount has changed,
    ' so change TotalHeadCount accordingly
    Call uidoc.FieldSetText( "TotalHeadCount",  _
    Cstr( totalHeadCount + _
    ( newHeadCount - oldHeadCount ) ) )
  End If
End Sub

次のスクリプトは、[By Category] ビューの最初の文書のカテゴリと件名の入ったダイアログボックスを表示します。

Sub Click(Source As Button)
  Dim db As NotesDatabase
  Dim s As New NotesSession
  Dim workspace As New NotesUIWorkspace
  Dim view As NotesView
  Dim doc As NotesDocument
  Set db = s.CurrentDatabase
  Set view = db.GetView( "By Category" )
  Set doc = view.GetFirstDocument
  Call workspace.DialogBox _
  ("Dialog Box", True, True, False, False, False,  _
  False, "Dialog Box", doc)
  Call doc.save (True, False)
End Sub